# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit kde
set-kdedir 3

DESCRIPTION="A theme package providing kdmtheme/gensplash/ksplash/background"
HOMEPAGE="http://www.kde-look.org/content/show.php/?content=46638"
SRC_URI="http://electrostorm.net/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RESTRICT="mirror"

DEPEND=""
RDEPEND=">=kde-misc/ksplash-engine-moodin-0.4.2"

# don't compile
src_compile() { 
	return
}

src_install() {
	# install kdm theme
	insinto ${KDEDIR}/share/apps/kdm/themes/${PN}
	doins kdmtheme/* || die "doins failed"

	# install ksplash theme
	insinto ${KDEDIR}/share/apps/ksplash/Themes/${PN}
	doins ksplash/* || die "doins failed"

	# fix paths in config
	sed -i \
		-e "s/Gentoo-black/black-gentoo/" \
		gensplash/1280x1024.cfg || die "config manipulation failed"
	# install gensplash theme to /etc/splash
	insinto /etc/splash/${PN}
	doins -r gensplash/* || die "doins failed"


	
	# install background
	mv gensplash/images/background* black-gentoo.png
	insinto ${KDEDIR}/share/wallpapers
	doins black-gentoo.png
}

pkg_postinst() {
	echo
	elog "This package does not pull gensplash, you have to install it by yourself!"
	elog "The splash theme has been installed to /etc/splash/black-gentoo."
	echo
}